server-configuration/flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    juanfont-headscale = {
      url = "github:juanfont/headscale/v0.23.0-alpha2";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, agenix, juanfont-headscale }:
    let
      pkgs = import nixpkgs { system = "x86_64-linux"; };
    in {
      packages.x86_64-linux.glauth = pkgs.callPackage ./pkgs/glauth.nix {};
      packages.x86_64-linux.cockpit-tailscale = pkgs.callPackage ./pkgs/cockpit-tailscale.nix {};

      nixosConfigurations.samsehu = nixpkgs.lib.nixosSystem {
        system = "x86_64-linux";
        modules = [
          ({config, pkgs, ...}: {
            nixpkgs.overlays = [ (final: prev: {
              juanfont-headscale = juanfont-headscale.packages.${prev.system};
              glauth = self.packages.${prev.system}.glauth;
              cockpit-tailscale = self.packages.${prev.system}.cockpit-tailscale;
            })];
          })
          ./agenix-config-module.nix
          ./configuration.nix
          ./services/glauth.nix
          agenix.nixosModules.default
        ];
      };
  };
}